
専門学校のVBA課題採点が予想以上にドラマチックな話
こんにちは「つけらっとゲームス」プログラム担当のとちです。
学生の皆さんは、あと30日くらいしたら楽しい冬休み前ですね。でも、その前に定期テストがあったり、課題の提出期限があったりで大変でしょう。
え?「採点する方も大変でしょ?」って?
そう言っていただけると有難いですが…確かに大変ではあるものの「面白い」部分もあるんです。今回はちょっと前に締め切った課題、その採点時にあったお話をしたいと思います。
えーと、この記事の対象はプログラミングを学び始めた方、これから学ぶ方が主な対象となるんですかね、自分でゲーム作れちゃうような方は「学生の考え方も面白いな」って感じで楽しめる……といいなぁ。
ちょっと前フリ(前提条件)が長めです。
普段から弊サークルの記事をご覧になっている方は、どんなことを教えているかご存知でしょうから、お好みで読み飛ばしてね!
この課題の前提条件
担当しているのはシステム系学科のある専門学校の1年目の学生。ゲーム開発特化の学科ではありません。んで、この課題だけに限らず、わたしが担当している時間はAIに相談してもいい、ググってもいい、友人に相談してもいい。処理に必要な変数や配列等は追加して良いという自由なスタイルです。
4~5月は変数や配列の考え方からスタートし、6~7月は基本的な探索アルゴリズム、8~9月は基本的な整列アルゴリズムを使ってわたしがある程度作った仕様と設計に則って簡易システムを開発して貰いました。
10月は(今回の課題)簡単な仕様と中途半端な開発状況のファイルを渡しました。これを要件を満たしたシステムとして完成させる課題です。
【使ったプログラミング言語は何ですか?】
システム開発はExcel(VBA)を使います。他の時間ではPythonも習うんですけど、VBAって変数定義の型が厳しいので、本当の基礎から学ぶのであれば、アリだなーと思っています。来年度はUnityも学ぶので、やっぱり型の定義をするc#を触るんです。その練習にもなりますしね。
ちなみに11月は簡単な仕様だけ渡し、必要要件を満たしたシステムを設計する課題。そして12月以降は仕様から考えて貰う流れです。
実際に使用した問題
以下はその問題となります。皆さんもちょっとだけ頭の中でどうやって作るかを想像してみましょう。まずは使用するデータのスクショを貼りますね。

次は、まだ中途半端な機能しか持っていないユーザーフォームです。
こちらもスクリーンショットをぺたり。
上のコンボボックスは「価格」「攻撃力」「種別・価格」「種別・攻撃力」を選択できるようになっており、下のコンボボックスは「昇順」「降順」が設定されています。

チェックボックスにチェックが入っていない種別のアイテムは画面表示をしない。「並び替え」ボタンを押したら、右側の「並び替え結果」と書かれているラベルオブジェクトにソート結果を表示するシステムを作りたい。
次のスクショは「価格」の「昇順」の並び替えをした場合。
このように表示されたらOKです。

以下のコードは最初に用意されているモノです。
ちょっとだけ解析するとわかりますが、フォーム初期化時にワークシートからデータを読み取って配列に格納するコードですね。
Option Explicit
'────────────────────────────────
' 配列群i
'────────────────────────────────
Dim iType(0 To 15) As Integer '【配列定義】種別
Dim iName(0 To 15) As String '【 〃 】アイテム名
Dim iPow(0 To 15) As Integer '【 〃 】攻撃力
Dim iGold(0 To 15) As Integer '【 〃 】価格
'────────────────────────────────
' UserForm_Initialize フォーム初期化時
'
' 引数:なし
'
' 戻値:なし
'
'────────────────────────────────
Private Sub UserForm_Initialize()
'----------------------------------------------------
' ワークシートから配列にデータを代入
'----------------------------------------------------
Dim ix As Integer '【変数定義】配列にデータを入れるための添字
Dim ws As Worksheet '【 〃 】ワークシート
Set ws = Sheets("ItemSheet") ' データのあるワークシートを変数にセット
For ix = 0 To UBound(iType) ' ■ ワークシートからデータを取得するループ
iType(ix) = ws.Cells(ix + 3, 1).Value ' ├ iType に 種別 を格納
iName(ix) = ws.Cells(ix + 3, 2).Value ' ├ iName に アイテム名 〃
iPow(ix) = ws.Cells(ix + 3, 3).Value ' ├ iPow に 攻撃力 〃
iGold(ix) = ws.Cells(ix + 3, 4).Value ' ├ iGold に 価格 〃
Next ix ' └ ループ終端
'----------------------------------------------------
' コンボボックスに選択肢を追加
'----------------------------------------------------
ComboBox1.AddItem "価格", 0 ' ComboBox1 価格
ComboBox1.AddItem "攻撃力", 1 ' 〃 攻撃力
ComboBox1.AddItem "種別・価格", 2 ' 〃 種別・価格
ComboBox1.AddItem "種別・攻撃力", 3 ' 〃 種別・攻撃力
ComboBox1.ListIndex = 0 ' 〃 初期表示は0番の価格
ComboBox2.AddItem "昇順", 0 ' ComboBox2 昇順
ComboBox2.AddItem "降順", 1 ' 〃 降順
ComboBox2.ListIndex = 0 ' 〃 初期表示は0番の昇順
End Subこの課題の問題文はPDFで配布しています。
まだ色々と確認したいところがありますよね?
例えば上のスクショの様に同じ価格だった場合の並び順はどうするのか?
他には、どこまで動作したら合格点だよ、他にもこんなのがあると加点するよ、という採点基準も一緒に公開しました。
さて、いかがでしょう?
皆さんも「こんな感じに処理しよう」とか「この手順ならアレが足りないから追加したい」とか色々と頭に思い浮かんでくると思います。細かいところまで考えなくても、経験がある方なら既にロジックが生まれているハズ。
では、わたしが採点していて「良い工夫!」とニヤリとしたのは何なのか、学生たちがどんな取り組みをしたのかは、次の節でお話しますね。
前フリが長くなってごめんなさいね!
ロジック的に面白い!
この課題のソートは「価格」「攻撃力」「種別・価格」「種別・攻撃力」の、「昇順」と「降順」をユーザーフォームのコンボボックスで切り替えます。
8種類の並び替えが発生しうるシステムだと分かりますね。
これ、真面目に if文で分岐させるとかなりネストが深いコードになります。
ネストが深いっていう表現が伝わるかなぁ…ループ文や、If文などで「何重にも深い入れ子の中に入っている状態」の事をいいます。今回の課題を特に工夫せずに書くと下の画像の様にループの中にループがあり、且つ分岐が大量にあるコードになります。

経験者にとってはこれくらいのループと分岐だと、そこまで深いとは感じないかも、ですが4月から学んだ学生にとっては十分に深いんですよね。ネストが深いと読むのが大変ですし、いざ修正が必要となった時に、どこを修正したらいいか判断するのが難しいんです。
その改善方法として、降順の場合は対象となるデータに「マイナスの掛け算をする」っという工夫をした学生がいました。これは良い工夫です。
【「どういうこと?」と思った方に解説】
手習いの杖が100G、青銅の剣が200Gです。
価格の昇順であればこのままでOKです。
価格の降順にしたい場合は -1を乗算します。
プログラムは昇順のモノをそのまま使います。
すると…青銅の剣が-200G、手習いの杖は-100Gの順に並びます。
この工夫をするだけで画像で表現すると下のようになります。プログラム自体が短く、ネストも浅くなりました!
こういうのを見ると嬉しくなりますね! これは加点対象です!

UIで工数を減らすのが面白い!
今回のユーザーフォーム、問題として配布された中身を見ると、ソート結果を表示するのはラベルオブジェクトが1つだけです。
ソート結果を綺麗に表示する為には文字列操作をする処理を考える必要が出てきます。特に何も考えずに単純に各データをくっつけると、以下のスクショのような表示になっちゃいます。

これだと見づらいですよね?
経験者の方は、やろうと思えば簡単にできるんですけど、初心者にとって、文字列操作は結構難しい処理なんです…さぁ困ったぞ。
処理に必要な配列や変数は自由に追加しても構いません。
なので、ある学生は自由にラベルオブジェクトを追加しました!

アイテム名は全角で長さが違う、攻撃力と価格は数字として右揃えにしたいけど桁が違う。そんな制御を一切しなくてもいいので、これだと文字列操作がすごく楽になるんですよね。
これは工夫が見られるので加点しましょう!
自分で調べて書いたのが面白い!
わたしの担当する授業時間は1週間に6時間。
結構長いですよね、でも基本的なアルゴリズムを教えて、基本的なVBAの書き方を教えて、基本的なVBEの使い方を教えて、とりあえず動くような環境を作ったら、あとは自由に課題に取り組んで貰っています。
え? それは講師の怠慢だって?
これがね、意外と彼らの後ろで見ているのって辛いんですよ。エラーが発生したら、わたしがデバッグする方が楽でしょう。学生がエラー箇所を探し修正するよりはるかに速いでしょう。でも、それじゃ意味がないんです。
AIに聞いてもいい、ググってもいい、友達に聞いてもいい、もちろん、わたしに聞いてもいい。聞くにしても自分で何に困っているのかを説明できないとAIであろうが、検索エンジンであろうが、友人、わたしもわかりません。
(ある意味で、困るような経験を敢えてさせているんだから怠慢かも…)
でも、困っている内容を説明し、それに対する答えが分かったら、意外と忘れないもんなんですよ…ちょっと違うな、忘れても調べ方を覚えているから、すぐに調べ直せるんですよ。これがすごく大事。
前述したとおり、この課題をループ文とif文を使って普通に処理しようとすると初心者にとっては結構なネストの深さになります。コードを書いている学生本人でも途中で何をどこまで書いたのか混乱します。コードを整理したくなりますよね?
恐らくAIか何かに教えて貰ったのでしょう、Select Case文を使っている学生が複数いました。調べた学生から徐々に伝播していったのかもしれません。
またある学生は、イミディエイトウィンドウを使って自分の処理をしっかりとデバッグしていました。これまた偉い。配列や変数の中身がどうなっているのかを追いかけるのはミスった時に非常に良い確かめ方ですからね。
このように学生それぞれが工夫や頑張った痕跡がコードには残っているものです。こういうの見つけるとわたしは嬉しいんですよ。自発的に問題解決に動いている。業務だと当たり前ですがこれも加点対象とします!
その他にも処理前に冗長ではあっても初期化をしっかりする学生もいました。自分が書いたコードにコメントをしっかりとつける学生もいました。
わたしたち、経験者にとっては当たり前ですよ、でも評価したいじゃないですか!
解答例のコードは複数用意した!
さて、このように採点していくんですけど、学生にとっては、自由、自由って言われても結局はどれが正解なの?という不安が出てくることでしょう。
だから彼らが実習している間に、わたしも同じ問題を解いておきます。
すっごく長いコードになったのでテキストファイルにしました。
これは多くの学生たちが提出するであろうコードの形にしたものです。
しかし、いま貼り付けたテキストファイルのコードとは違う解答例も用意します。こっちの手法の方がわかりやすいんかなーっていうやり方です。
以下に貼り付けますね。
ただ、コードにすると長いんだよなぁ~。
この後で、どこが違うのかもちゃんと説明していますので特別中身を確認したい方以外は読み飛ばしてOKです。
Option Explicit
'────────────────────────────────
' 配列群i
'────────────────────────────────
Dim iType(0 To 15) As Integer '【配列定義】種別
Dim iName(0 To 15) As String '【 〃 】アイテム名
Dim iPow(0 To 15) As Integer '【 〃 】攻撃力
Dim iGold(0 To 15) As Integer '【 〃 】価格
Dim iKey(0 To 15) As Long '【 〃 】(ADD)ソートキー
'────────────────────────────────
' UserForm_Initialize フォーム初期化時
'
' 引数:なし
'
' 戻値:なし
'
'────────────────────────────────
Private Sub UserForm_Initialize()
'----------------------------------------------------
' ワークシートから配列にデータを代入
'----------------------------------------------------
Dim ix As Integer '【変数定義】配列にデータを入れるための添字
Dim ws As Worksheet '【 〃 】ワークシート
Set ws = Sheets("ItemSheet") ' データのあるワークシートを変数にセット
For ix = 0 To UBound(iType) ' ■ ワークシートからデータを取得するループ
iType(ix) = ws.Cells(ix + 3, 1).Value ' ├ iType に 種別 を格納
iName(ix) = ws.Cells(ix + 3, 2).Value ' ├ iName に アイテム名 〃
iPow(ix) = ws.Cells(ix + 3, 3).Value ' ├ iPow に 攻撃力 〃
iGold(ix) = ws.Cells(ix + 3, 4).Value ' ├ iGold に 価格 〃
Next ix ' └ ループ終端
'----------------------------------------------------
' コンボボックスに選択肢を追加
'----------------------------------------------------
ComboBox1.AddItem "価格", 0 ' ComboBox1 価格
ComboBox1.AddItem "攻撃力", 1 ' 〃 攻撃力
ComboBox1.AddItem "種別・価格", 2 ' 〃 種別・価格
ComboBox1.AddItem "種別・攻撃力", 3 ' 〃 種別・攻撃力
ComboBox1.ListIndex = 0 ' 〃 初期表示は0番の価格
ComboBox2.AddItem "昇順", 0 ' ComboBox2 昇順
ComboBox2.AddItem "降順", 1 ' 〃 降順
ComboBox2.ListIndex = 0 ' 〃 初期表示は0番の昇順
End Sub
'────────────────────────────────
' SortStart_Click ソート実行ボタン
'
' 引数:なし
'
' 戻値:なし
'
'────────────────────────────────
Private Sub SortStart_Click()
Dim i As Integer '【変数定義】未整列部分との区切り添え字(index)
Dim j As Integer '【 〃 】整列済部分を探索する添え字(index)
Dim wStSW As Integer '【 〃 】ソート対象項目 [0]価格 [1]攻撃力 [2]種別・価格 [3]種別・攻撃力
Dim wAsDe As Integer '【 〃 】ソート昇降順 [0]昇順 [1]降順
Dim IreFg As Boolean '【 〃 】入替発生フラグ
Dim wType As Integer '【 〃 】退避用 - 種別
Dim wName As String '【 〃 】退避用 - アイテム名
Dim wPow As Integer '【 〃 】退避用 - 攻撃力
Dim wGold As Integer '【 〃 】退避用 - 価格
Dim wKey As Long '【 〃 】退避用 - ソートキー
'----------------------------------------------------
' ソートキーの作成
'----------------------------------------------------
wStSW = ComboBox1.ListIndex ' ComboBox1 から ソート対象項目を取得
wAsDe = ComboBox2.ListIndex ' ComboBox2 から ソート昇降順 を取得
Call Create_SortKey(wStSW) ' ソートキーの作成
'----------------------------------------------------
' 挿入ソート
'----------------------------------------------------
For i = 1 To UBound(iType) ' ■ 未整列部分から配列最後尾までループ
wType = iType(i) ' ├ 挿入対象のデータを退避エリアに代入
wName = iName(i) ' ├ 〃 〃
wPow = iPow(i) ' ├ 〃 〃
wGold = iGold(i) ' ├ 〃 〃
wKey = iKey(i) ' ├ 〃 〃
' │
For j = i - 1 To 0 Step -1 ' ├◆ 整列済部分の最後尾から配列の先頭までループ
IreFg = False ' │├ 入替発生フラグを初期化(False)
If wAsDe = 0 And wKey < iKey(j) Then IreFg = True ' │├◆ ソート昇降順が[0]昇順の場合 >> 挿入対象が小さい場合は入替発生
If wAsDe = 1 And wKey > iKey(j) Then IreFg = True ' │├◆ ソート昇降順が[1]降順の場合 >> 挿入対象が大きい場合は入替発生
If IreFg = True Then ' │├◆ 入替発生フラグがTrueの場合
iType(j + 1) = iType(j) ' ││├ 退避データを挿入する空きを作る
iName(j + 1) = iName(j) ' ││├ 〃 〃
iPow(j + 1) = iPow(j) ' ││├ 〃 〃
iGold(j + 1) = iGold(j) ' ││├ 〃 〃
iKey(j + 1) = iKey(j) ' ││├ 〃 〃
Else ' ││◆ 入替発生フラグがFalseの場合
Exit For ' ││└ ループを抜ける
End If ' ││
Next j ' │└ ループ終端
' │
iType(j + 1) = wType ' ├ 退避データ挿入
iName(j + 1) = wName ' ├ 〃
iPow(j + 1) = wPow ' ├ 〃
iGold(j + 1) = wGold ' ├ 〃
iKey(j + 1) = wKey ' ├ 〃
Next i ' └ ループ終端
'----------------------------------------------------
' ソート結果をラベルに表示
'----------------------------------------------------
Call Display_SortAns
End Sub
'────────────────────────────────
' Create_SortKey ソートキーの作成
'
' 引数:sw ソート対象項目
'
' 戻値:なし
'
'────────────────────────────────
Private Sub Create_SortKey(sw As Integer)
Dim i As Integer '【変数定義】配列群i探索用添え字(index)
For i = 0 To UBound(iKey) ' ■ 未整列部分から配列最後尾までループ
If sw = 0 Then iKey(i) = CLng(iGold(i)) * 10 + iType(i) ' ├ ソートキー算出 価格順
If sw = 1 Then iKey(i) = iPow(i) * 10 + iType(i) ' ├ ソートキー算出 攻撃力順
If sw = 2 Then iKey(i) = CLng(iType(i)) * 10000 + iGold(i) ' ├ ソートキー算出 種別・価格順
If sw = 3 Then iKey(i) = CLng(iType(i)) * 10000 + iPow(i) ' ├ ソートキー算出 種別・攻撃力順
Next i ' └ ループ終端
End Sub
'────────────────────────────────
' Display_SortAns ソート結果をラベルに表示
'
' 引数:なし
'
' 戻値:なし
'
'────────────────────────────────
Private Sub Display_SortAns()
Dim i As Integer '【変数定義】配列群i探索用添え字(index)
Dim title As String '【 〃 】ソート結果の見出し
Dim tx As String '【 〃 】ソート結果の内容
Dim nm As String '【 〃 】編集用 - アイテム名
Dim pw As String '【 〃 】編集用 - 攻撃力
Dim gd As String '【 〃 】編集用 - 価格
Dim ok As Integer '【 〃 】チェックボックスの確認スイッチ
Dim okCnt As Integer '【 〃 】チェックボックスの確認スイッチでOK件数のカウント
title = "種別 アイテム名 攻撃力 価格" & vbCr ' ソート結果の見出し
'
For i = 0 To UBound(iType) ' ■ラベルに表示するテキストを作るループ
ok = 0 ' ├ チェックボックスの確認スイッチを初期化
If iType(i) = 1 And CheckBox1.Value = True Then ok = 1 ' ├ 種別が1で、チェックボックス1にチェックがあったら OK
If iType(i) = 2 And CheckBox2.Value = True Then ok = 1 ' ├ 種別が2で、チェックボックス2にチェックがあったら OK
If iType(i) = 3 And CheckBox3.Value = True Then ok = 1 ' ├ 種別が3で、チェックボックス3にチェックがあったら OK
If iType(i) = 4 And CheckBox4.Value = True Then ok = 1 ' ├ 種別が4で、チェックボックス4にチェックがあったら OK
If iType(i) = 5 And CheckBox5.Value = True Then ok = 1 ' ├ 種別が5で、チェックボックス5にチェックがあったら OK
If ok = 1 Then ' ├◆チェックボックスの確認スイッチがOKの場合
nm = Left(iName(i) & " ", 7) ' │├ 編集 - アイテム名
pw = " " & iPow(i) ' │├ 編集 - 攻撃力
pw = Mid(pw, Len(pw) - 5) ' │├ 編集 - 攻撃力
gd = " " & iGold(i) ' │├ 編集 - 価格
gd = Mid(gd, Len(gd) - 7) ' │├ 編集 - 価格
tx = tx & " " & iType(i) & " " ' │├ 編集 - テキストの連結
tx = tx & nm & pw & gd & vbCr ' │├ 編集 - テキストの連結
okCnt = okCnt + 1 ' │└ チェックボックスの確認スイッチでOK件数のカウントUP
End If ' │
Next i ' └ ループ終端
'----------------------------------------------------
' 編集したテキストがあれば表示
'----------------------------------------------------
If okCnt >= 1 Then
SortAns.Caption = title & tx
Else
SortAns.Caption = "該当データがありません"
End If
End Sub
これだとかなり短くなります。
コードを解説するためのコメントや、コードを追いやすくするために冗長な書き方をしていますが、それでもテキストファイルで貼り付けたコードよりは短いですね。
何が違うのか…
これね、記事冒頭のデータを見た時点で「アレが足りない」となった方なら、こんな処理すると思うんですよ。もう一回データを貼り付けますよ。

このデータにはユニークなキーが無いんです。問題文があるPDFには、それぞれの最大桁数も書いていまして…そうなるとソート用にキーを作ったらネストがすごく浅くなる想像がつくと思います。
【「どういうこと?」と思った方に解説】
例えば、種別・攻撃力順で並び替えするとしましょう。
種別は1桁、攻撃力は最大で2桁です。
だったら、種別 × 100 + 攻撃力 をソート用のキーにすればいいんです。
・青銅の剣は種別1の攻撃力10なので、さっきの式で言うと 110 です。
・門番の槍は種別2で攻撃力8なので、式を通すと 208 です。
これなら昇順でも降順でも比較が楽になりますよね?
サンプルコードでは種別・価格のソートキーと統一性を出すために種別 × 10000で計算していますが、考え方は同じです。
えーと、わたしが担当している教科名は「システム設計」と言います。
アルゴリズムは大事です。各種ツール類の使い方も大事です。
そしてシステム系専門学校といえば、外からの印象はコードの勉強をしているイメージでしょう。間違っていません。コード書いてますもんね。
でも、問題解決法は難しいコードを書くだけじゃない…
そもそも仕様や設計に穴があったら塞いでおくし、効率が上がるなら先輩や上司、場合によってはお客様に「こういう改修をしたらいいのではないでしょうか?」と言える人の方がいいと思うんですよ。
参考書に書いてある練習問題を解くのも大事ではあるモノの、その参考書の問題の範囲から思考や発想が抜け出せないなら勿体なさすぎるんですよね。
おわりに
毎年この時期は、このように与えられた問題を解くだけでなく、仕様だけ渡されて設計をする課題、そして仕様から考える課題にシフトしていく季節。
これをスルスルと解ける学生もいます。逆に苦手な学生もいます。
穴埋め問題では確かに決められた仕様、設計の範囲内でしか正解はありませんが、何かを作る時ってのは正解はたくさんあるんですよ。
今回の記事ではソートキーを作る方法が正解っぽく書きましたが、そんなことはない。学生のみんなが出した方法だって正解です。
1年あたり5%くらいですがソートキーを作る学生が出てくる年もあるんですけど、今年の学生が劣っているとかではなく、おそらく期限に対するリスク管理をしたんだと思います。
キーを作ろうとした痕跡のある学生もいたんですけど、ちょうど学校内で風邪が流行った時期だったこと、期限までに絶対にどんな形でもいいから提出するように言い続けたこともあって、いま確実に解ける方法を選んだのでしょう。たぶん、きっと…
来年も(契約継続したら)似たような課題を出そうと思っています。
というわけで、採点も結構面白かったりするって言うお話でした。
では、また別の記事でお会いしましょう!
以降はオススメ記事の紹介です。
「読むとゲームができる」記事は、このマガジンにまとめています。
情報関連の勉強をしている方、復習したい方にはコチラ!
基本情報技術者試験のアルゴリズムとか苦手!って方にもオススメです。