メインコンテンツへスキップ
見出し画像

AIといっしょに組み込み開発16日目:ESP32C3で作った植物モニターを実戦配備

    今朝は3時半に自力でおきました。助手の猫さんは寒かったからか夜中にかみさんの布団に来て寝ていました。「休憩!」と呼びにも来ないでまだ寝ているようです。そのうち布団にもぐるようになると思います。

    昨日、温度、湿度、土壌水分量をモニターするプログラムができたので、実際にニャンベジの栽培で使ってみることにしました。

    ESP32C3で同じ回路の配線をしました。ESP32C6で開発したプログラムがそのまま動作するかと思っていましたが、甘くはなかったです。

    • LEDがボードについていない

    • GPIOの配置が微妙に違う

    • 土壌水分センサーの測定値がおかしい

    LEDは外付けにして、GPIOのピン番号は数値ではなく定義されてるシンボルに変えて対策しました。土壌水分センサーは、水に付けた時と、乾燥した時のアナログ電圧の値をメモして修正しました。

    画像

    センサー毎に違うのか?ESP32毎に違うのか謎ですが、補正の必要ない土壌水分センサーがないかと、販売サイトを探したくなりました。

    いろいろ修正してPCからUSBで接続した状態では、うまく動作するようになりました。
    そこで、

    画像
    ESP32C3植物モニター
    画像


    のような構成で動かしてみると

    • プログラムが起動しないようだ

    • 少し時間が経つとバッテリーの電源が切れる

    という状態になってしまいました。
    プログラムが起動しない方は、 Gemini CLIさんにソースコードをみてもらいました。

    画像

    言われてみれば、その通りです。修正してもらいました。
    電源が切れるほうは、Web板のGeminiさんに聞いてみるとモバイルバッテリーは、電力が少ないと自動で停止する機能があるそうで、ANKERの場合、電源ボタンを2回押すとイアフォンの充電モードのような電力が小さくても切れないモードになると教えてくれました。
    やってみると、たしかにモバイルバッテリーの緑のLEDが点灯して電源がきれなくなりました。

    ESP32C3のほうが電力を使うようです。Deep Sleep中も少し電気が流れているようです。
    どのくらい動作するか実験してみます。

    ちなむ、ESP32C3用のプログラムは、

    #include <WiFi.h>
    #include <PubSubClient.h>
    #include <Adafruit_Sensor.h>
    #include <DHT.h>
    #include <DHT_U.h>
    #include <ArduinoJson.h>
    #include "config.h"
    
    #define DHTPIN D10                   // Digital pin connected to the DHT sensor
    #define DHTTYPE DHT22                // DHT22
    #define SOIL_MOISTURE_SENSOR_PIN A1  // Soil Moisture Sensor
    #define LED_BUILTIN D2
    
    #define uS_TO_S_FACTOR 1000000ULL /* Conversion factor for micro seconds to seconds */
    #define TIME_TO_SLEEP 55          /* Sleep for 55s will + 5s delay for establishing connection => data reported every 1 minute */
    
    DHT_Unified dht(DHTPIN, DHTTYPE);
    WiFiClient espClient;
    PubSubClient mqtt_client(espClient);
    
    // JSON Data
    JsonDocument doc;
    static char outputtext[100] = "";
    
    
    // Function Declarations
    bool initSensors();
    bool connectToWiFi();
    bool publishToMQTT();
    
    void setup() {
      Serial.begin(115200);
      // while (!Serial) delay(100);
      pinMode(D0, INPUT_PULLUP);                 // BUTTON
      pinMode(LED_BUILTIN, OUTPUT);              // LED
      pinMode(SOIL_MOISTURE_SENSOR_PIN, INPUT);  // Soil Moisuture sensor
      analogSetAttenuation(ADC_11db);
      delay(100);
      digitalWrite(LED_BUILTIN, LOW);
      while (digitalRead(D0) == LOW) {
        Serial.print(".");
        digitalWrite(LED_BUILTIN, HIGH);
        delay(500);
        digitalWrite(LED_BUILTIN, LOW);
        delay(500);
      }
      if (initSensors()) {
        if (connectToWiFi()) {
          publishToMQTT();
        }
      }
      digitalWrite(LED_BUILTIN, HIGH);
      Serial.println("");
      Serial.println("Going to sleep now");
      esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);
      esp_deep_sleep_start();
    }
    
    bool initSensors() {
      // Initialize device.
      dht.begin();
      Serial.println(F("DHT22 Unified Sensor Example"));
      // Print temperature sensor details.
      sensor_t sensor;
      dht.temperature().getSensor(&sensor);
      Serial.println(F("------------------------------------"));
      Serial.println(F("Temperature Sensor"));
      Serial.print(F("Sensor Type: "));
      Serial.println(sensor.name);
      Serial.print(F("Driver Ver:  "));
      Serial.println(sensor.version);
      Serial.print(F("Unique ID:   "));
      Serial.println(sensor.sensor_id);
      Serial.print(F("Max Value:   "));
      Serial.print(sensor.max_value);
      Serial.println(F("°C"));
      Serial.print(F("Min Value:   "));
      Serial.print(sensor.min_value);
      Serial.println(F("°C"));
      Serial.print(F("Resolution:  "));
      Serial.print(sensor.resolution);
      Serial.println(F("°C"));
      Serial.println(F("------------------------------------"));
      // Print humidity sensor details.
      dht.humidity().getSensor(&sensor);
      Serial.println(F("Humidity Sensor"));
      Serial.print(F("Sensor Type: "));
      Serial.println(sensor.name);
      Serial.print(F("Driver Ver:  "));
      Serial.println(sensor.version);
      Serial.print(F("Unique ID:   "));
      Serial.println(sensor.sensor_id);
      Serial.print(F("Max Value:   "));
      Serial.print(sensor.max_value);
      Serial.println(F("%"));
      Serial.print(F("Min Value:   "));
      Serial.print(sensor.min_value);
      Serial.println(F("%"));
      Serial.print(F("Resolution:  "));
      Serial.print(sensor.resolution);
      Serial.println(F("%"));
      Serial.println(F("------------------------------------"));
      return true;
    }
    
    bool connectToWiFi() {
      WiFi.begin(ssid, password);
      Serial.print("Connecting to WiFi");
      int i = 200;
      while (WiFi.status() != WL_CONNECTED) {
        digitalWrite(LED_BUILTIN, HIGH);
        delay(500);
        digitalWrite(LED_BUILTIN, LOW);
        delay(500);
        Serial.print(".");
        i--;
        if (i < 0) {
          Serial.println("\nFailed");
          return false;
        }
      }
      Serial.println("\nConnected");
      return true;
    }
    
    bool publishToMQTT() {
      sensors_event_t event;
      dht.temperature().getEvent(&event);
      if (!isnan(event.temperature)) {
        doc["temperature"] = event.temperature;
      } else {
        Serial.println(F("Error reading temperature!"));
      }
      // Get humidity event and print its value.
      dht.humidity().getEvent(&event);
      if (!isnan(event.relative_humidity)) {
        doc["humidity"] = event.relative_humidity;
      } else {
        Serial.println(F("Error reading humidity!"));
      }
      doc["soil_moisture"] = getSoilMoisture();
      serializeJson(doc, outputtext, 100);
      mqtt_client.setServer(mqtt_broker, mqtt_port);
      mqtt_client.setKeepAlive(60);
      // mqtt_client.setCallback(mqttCallback);
      int i = 12;
      while (!mqtt_client.connected()) {
        String client_id = "esp32-client-" + String(WiFi.macAddress());
        Serial.printf("Connecting to MQTT Broker as %s.....\n", client_id.c_str());
        if (mqtt_client.connect(client_id.c_str())) {
          Serial.println("Connected.");
          Serial.printf("Publishing message: %s\n", outputtext);
          // Publish the message.
          if (mqtt_client.publish(mqtt_topic, outputtext)) {
            Serial.println("Publish ok");
            // Allow the client to process messages.
            mqtt_client.loop();
            // Disconnect from the broker.
            mqtt_client.disconnect();
            Serial.println("MQTT disconnected.");
            return true;
          } else {
            Serial.println("Publish failed");
            return false;
          }
        } else {
          Serial.print("Failed, rc=");
          Serial.print(mqtt_client.state());
          Serial.println(" try again in 5 seconds.");
          delay(5000);
          i--;
          if (i < 0) {
            Serial.println("Retry over.");
            return false;
          }
        }
      }
      return false;
    }
    
    // キャリブレーション値
    // この値を自分の環境に合わせて調整します。
    const float dryValue = 3449;  // 最も乾燥した土壌 (モジュールが空気中にある状態) のADC値の読み取り
    const float wetValue = 2219;  // 水
    
    
    float getSoilMoisture() {
      long sum = 0;
      for (int i = 0; i < 10; i++) {
        sum += analogRead(SOIL_MOISTURE_SENSOR_PIN);
        delay(2);
      }
      float rawValue = (float)sum / float(10);
    
      // ADC値から水分パーセンテージを計算する
      // map関数を使って、キャリブレーション値の範囲を0-100%に変換します。
      // wetValue < rawValue < dryValue の関係に基づき、map関数の引数を調整します。
      // 水分が多いほどrawValueは小さくなるため、dryValueからwetValueの範囲を0から100にマッピングします。
      float moisturePercent = map(rawValue, dryValue, wetValue, 0, 100.0);
    
      // 計算の逆転を防ぐために、値を0-100の範囲にクランプします
      if (moisturePercent < 0) {
        moisturePercent = 0;
      }
      if (moisturePercent > 100) {
        moisturePercent = 100;
      }
    
      Serial.print("Raw ADC Value: ");
      Serial.print(rawValue);
      Serial.print(" | Moisture Percentage: ");
      Serial.print(moisturePercent);
      Serial.println("%");
      return (moisturePercent);
    }
    
    void loop() {
    }

    です。

    明日に続く


     
     

    twsnmp

     
     
    私は、TWSNMP Managerの開発者です。 25年以上前に作ったソフトを今も多くの人に使っていただけて幸せです。 2021年:Docker版TWSNMP FC、2022年:スマホ版,2023年:シン・TWSNMP、2026年AI対応ログ分析ツールを開発しました。

    あなたへのおすすめ