Assess readiness for the v6 and v7 VM series

Applies to: ✔️ Linux VMs ✔️ Windows VMs

Workload patterns: ✔️ B. Image-based hosts · E. Customer-managed VMs · F. Stateful and clustered · G. Certified appliances — ❌ Not for A, C, or D

To move to the v6 or v7 series, start with a quick readiness check. Readiness is a short checklist focused on the platform underneath: boot mode, image, storage interface, network driver, and regional and zonal availability.

Greenfield deployments

For new deployments, you don't need to fix anything. Choose the v6 or v7 series intentionally and start clean:

• Confirm region and zone availability and quota for the chosen family.
• Note a fallback size, zone, or region before launch.
• Use infrastructure as code (Bicep or Terraform) for repeatability.
• Enable Trusted Launch (the default for Generation 2) for Secure Boot and vTPM.
• Deploy from a current Generation 2, NVMe-ready, MANA-ready marketplace or Azure Compute Gallery image.

Greenfield deployments can skip the remediation guidance that follows and go straight to sizing and capacity in Plan the modernization.

Brownfield modernization from the v2 through v5 series

Retiring v3 source series

Workloads on these series usually trigger several readiness signals at once. Check these signals for every v3 workload:

• Generation 1: Many v3 VMs are Generation 1. Plan a Generation 2 image. You can't convert Generation 1 Dv3 VMs to Generation 2 in place. For more information, see Decide a modernization approach.
• Image: Refresh custom images to a current Generation 2, NVMe-ready, and MANA-ready version.
• NVMe: The v3 series presents disks over SCSI. Replace hard-coded SCSI device paths with stable identifiers.
• MANA: Confirm the OS and driver meet the MANA version floors.
• Local disk: Every v3 size includes a local temporary disk. If the workload uses it, choose a d-suffixed target size, such as Ddsv6 or Edsv6, or relocate that data to a managed data disk.
• Region and quota: Capacity growth restrictions already block extra v3 quota. Request quota for the target family early in every region and zone you need.

If the v6 or v7 prerequisites block a v3 workload, the v5 series provides the smoothest transition. For more information, see Modernize to the v5 VM series.

What changes, and what doesn't

Hard gates

Two categories of workloads have a gate that comes before this checklist. Confirm the gate first. If the target family isn't supported, the remaining signals don't matter.

Readiness signals to check

Session-host golden images

For non-persistent session hosts — Azure Virtual Desktop pooled host pools, Citrix DaaS random (pooled) catalogs, and Omnissa Horizon floating instant-clone pools (pattern B) — the readiness signals above apply to the golden image, not to each session host. Assess the image once, and pay particular attention to two signals that bite hardest on session hosts:

• Low-level agents. Antivirus, EDR, and monitoring agents that install kernel or filter drivers must be current and signed to work with Secure Boot.
• Persistent data on the OS disk. This pattern assumes user profiles and application data already live outside the session host. Confirm that's true before you rebuild the image.

Persistent desktops don't follow this pattern. Azure Virtual Desktop personal host pools, Citrix DaaS static (dedicated) catalogs, and Omnissa Horizon dedicated assignments bind a user to a specific VM, so there's no shared image to assess once and no host to drain. Assess each one as a customer-managed VM, and expect the OS-disk data and hibernation signals in the preceding table to apply.

For the host replacement sequence, see Image-based desktop and application hosts.

Assessment checklist

Keep the checklist lean and platform-focused.

Scope

• Confirm sponsor and workload owner.
• Document business driver (capacity, performance, cost, or modernization).
• Identify source family (v2/v3/v4/v5) and deployment type (modernization or greenfield).
• Separate production and non-production.
• Agree on modernization window and success/rollback criteria.

Compute and capacity

• Select current size and target v6/v7 size.
• Confirm VM generation (Generation 2 path planned if the source is Generation 1).
• Confirm target region and zone requirement.
• Confirm quota and availability per wave; consider capacity reservation.
• Note fallback size or region.

OS and image

• Support OS version; image is Generation 2, NVMe, and MANA ready.
• Azure Disk Encryption, BitLocker, or similar.
• Rebuild and validate custom gallery images once; enable boot diagnostics for the pilot.
• Use Azure Image Builder and Azure Compute Gallery for image build and versioning to ensure repeatability.

Storage

• Inventory OS and data disks; check disk-path references for hard-coded SCSI paths.
• Review temporary and local disk use; confirm page file, tempdb, and scratch placement.
• Take backup or snapshot before cutover; confirm Azure Backup support for Generation 2 and Trusted Launch.

Networking

• Confirm MANA OS and driver readiness.
• For network appliances: confirm NIC count, IP forwarding, and vendor support for the family.

Commercial

• Replan family-scoped reservations and savings plans so discount coverage follows the workload.

Inventory query (Azure Resource Graph)

The following Azure Resource Graph query surfaces the items that gate a clean move: size, generation, OS, image source, disk controller type, and more. Run this query in the portal's Resource Graph Explorer or via az graph query.

For more queries, see Starter queries.

resources
| where type =~ 'microsoft.compute/virtualmachines'
| extend p = properties
// ---- identity & placement ----
| extend
    resourceId          = id,
    availabilityZone    = tostring(zones[0]),
    availabilitySetId   = tostring(p.availabilitySet.id),
    vmssId              = tostring(p.virtualMachineScaleSet.id),
    platformFaultDomain = tostring(p.platformFaultDomain)
| extend
    availabilitySetName = iff(isnotempty(availabilitySetId), tostring(split(availabilitySetId, '/')[-1]), ''),
    vmssName            = iff(isnotempty(vmssId),            tostring(split(vmssId, '/')[-1]), '')
| extend
    membershipModel = case(
        isnotempty(vmssId),            'VMSS Flex',
        isnotempty(availabilitySetId), 'Availability Set',
                                       'Standalone'),
    zonePlacement   = iff(isnotempty(availabilityZone), 'Zonal', 'Regional')
// ---- compute & generation ----
| extend
    vmSize            = tostring(p.hardwareProfile.vmSize),
    hyperVGeneration  = tostring(p.extended.instanceView.hyperVGeneration)
// ---- power state + data quality ----
| extend
    vmState              = tostring(p.extended.instanceView.powerState.displayStatus)
| extend
    instanceViewCaptured = iff(isempty(hyperVGeneration) and isempty(vmState), 'No', 'Yes')
// ---- OS & image ----
| extend
    osType            = tostring(p.storageProfile.osDisk.osType),
    osVersion         = tostring(p.extended.instanceView.osVersion),
    computerName      = tostring(p.extended.instanceView.computerName),
    isMarketplaceVm   = isnotempty(plan),
    imagePublisher    = tostring(p.storageProfile.imageReference.publisher),
    imageOffer        = tostring(p.storageProfile.imageReference.offer),
    imageSku          = tostring(p.storageProfile.imageReference.sku),
    imageVersion      = tostring(p.storageProfile.imageReference.exactVersion)
// ---- storage / disks ----
| extend
    diskControllerType= tostring(p.storageProfile.diskControllerType),
    osDiskType        = tostring(p.storageProfile.osDisk.managedDisk.storageAccountType),
    osDiskSizeGB      = toint(p.storageProfile.osDisk.diskSizeGB),
    ephemeralOsDisk   = iff(tostring(p.storageProfile.osDisk.diffDiskSettings.option) =~ 'Local', 'Yes', 'No'),
    dataDiskCount     = array_length(p.storageProfile.dataDisks)
// ---- capabilities / licensing ----
| extend
    hibernationEnabled= tostring(p.additionalCapabilities.hibernationEnabled),
    ultraSsdEnabled   = tostring(p.additionalCapabilities.ultraSSDEnabled),
    licenseType       = tostring(p.licenseType)
// ---- network (VM level) ----
| extend
    nicCount          = array_length(p.networkProfile.networkInterfaces)
// ---- security & encryption ----
| extend
    securityType      = tostring(p.securityProfile.securityType),
    secureBootEnabled = tostring(p.securityProfile.uefiSettings.secureBootEnabled),
    vTpmEnabled       = tostring(p.securityProfile.uefiSettings.vTpmEnabled),
    adeOsDiskEnabled  = tostring(p.storageProfile.osDisk.encryptionSettings.enabled)
// ---- NIC flags: any NIC on the VM ----
| extend joinKey = tolower(tostring(id))
| join kind=leftouter (
    resources
    | where type =~ 'microsoft.network/networkinterfaces'
    | extend vmId = tolower(tostring(properties.virtualMachine.id))
    | where isnotempty(vmId)
    | summarize
        anyAccelNet = countif(tobool(properties.enableAcceleratedNetworking) == true),
        anyIpFwd    = countif(tobool(properties.enableIPForwarding) == true)
      by vmId
) on $left.joinKey == $right.vmId
| extend
    acceleratedNetworking = iff(coalesce(anyAccelNet, 0) > 0, 'Yes', 'No'),
    ipForwarding          = iff(coalesce(anyIpFwd, 0) > 0, 'Yes', 'No')
| project
    name, resourceGroup, location,
    membershipModel, zonePlacement, availabilityZone, vmssName, availabilitySetName, platformFaultDomain,
    vmSize, hyperVGeneration,
    vmState, instanceViewCaptured,
    osType, osVersion, computerName, isMarketplaceVm,
    imagePublisher, imageOffer, imageSku, imageVersion,
    diskControllerType, osDiskType, osDiskSizeGB, ephemeralOsDisk, dataDiskCount,
    hibernationEnabled, ultraSsdEnabled, licenseType,
    nicCount, acceleratedNetworking, ipForwarding,
    securityType, secureBootEnabled, vTpmEnabled, adeOsDiskEnabled,
    subscriptionId, resourceId, vmssId, availabilitySetId
| order by membershipModel asc, vmSize asc, name asc

For the CPU decode, use the following table:

Exit criteria

• You clear hard gates: SAP workloads have a certified target size, and appliance workloads have written vendor support for the exact family.
• Workloads are scored as ready now, ready after a small refresh, or plan the region or family.
• Target family, region, zone, and quota or capacity plan are documented.
• Any small remediation is assigned.
• Pilot (or greenfield first deployment) is selected.
• Rollback approach is noted, and workload owners approve the first wave.

Next steps

• 3. Plan a workload modernization to the v6 and v7 series